API Parameters

Help about API syntax.

Grammar with Syntax Rules

Term Representation for Graphs

graphterm ::=		Graph = root node list. Details.
	[graphterm1] \| [ ].

graphterm1 ::=
	node \| node,graphterm1.

node ::=
	l(node_id,n(type,attributes,edges))	Node with ID / type / attributes / children.
\|	r(node_id).	Reference to a node.

edges ::=		Edge list.
	[edges1] \| [ ].

edges1 ::=
	edge \| edge,edges1.

edge ::=
	l(edge_id,e(type,attributes,node)).	Edge with ID / type / attributes / child.

attributes ::=		Attribute list. Details.
	[attributes1] \| [ ].

attributes1 ::=
	attribute \| attribute,attributes1.

attribute ::=
	a(string,string)	Attribute = key / value pair.
\|	m(menus).	Pop-up menu attribute. Details.

Graph Updates

mixed_updates ::=		Both forms in one list. Details.
	[mixed_updates1] \| [ ].

mixed_updates1 ::=
	mixed_update \| mixed_update,mixed_updates1.

mixed_update ::=
	node_update \| edge_update.

node_updates ::=		Add or delete nodes. Details.
	[node_updates1] \| [ ].

node_updates1 ::=
	node_update \| node_update,node_updates1.

node_update ::=
	delete_node(node_id)
\|	new_node(node_id,type,attributes).

edge_updates ::=		Add or delete edges. Details.
	[edge_updates1] \| [ ].

edge_updates1 ::=
	edge_update \| edge_update,edge_updates1.

edge_update ::=
	delete_edge(edge_id)
\|	new_edge(edge_id,type,attributes,node_id,node_id).
\|	new_edge_behind(edge_id,edge_id,type,attributes,node_id,node_id).

attr_changes ::=		Change attributes. Details.
	[attr_changes1] \| [ ].

attr_changes1 ::=
	attr_change \| attr_change,attr_changes1.

attr_change ::=
	node(node_id,attributes)
\|	edge(edge_id,attributes).

type_changes ::=		Change types. Details.
	[type_changes1] \| [ ].

type_changes1 ::=
	type_change \| type_change,type_changes1.

type_change ::=
	node(node_id,type)
\|	edge(edge_id,type).

Application Menus and Icons

menus ::=		Create menus. Details.
	[menus1] \| [ ].

menus1 ::=
	menu_entry \| menu_entry,menus1.

menu_entry ::=
	menu_entry(menu_id,menu_label)
\|	menu_entry_mne(menu_id,menu_label,menu_mne,menu_mod,menu_acc)
\|	menu_entry_disabled(menu_id,menu_label)
\|	submenu_entry(menu_id,menu_label,menus)
\|	submenu_entry_mne(menu_id,menu_label,menus,menu_mne)
\|	submenu_entry_disabled(menu_id,menu_label,menus)
\|	blank.

icons ::=		Create icons. Details.
	[icons1] \| [ ].

icons1 ::=
	icon_entry \| icon_entry,icons1.

icon_entry ::=
	icon_entry(icon_id,filename,lang_string)
\|	blank.

Visualization definitions

visual_rules ::=		Visualization defs. Details.
	[visual_rules1] \| [ ].

visual_rules1 ::=
	visual_rule \| visual_rule,visual_rules1.

visual_rule ::=
	nr(type,attributes)
\|	er(type,attributes).

Strings

node_ids ::= [node_ids1] \| [ ].		List of node IDs.

node_ids1 ::= node_id \| node_id,node_ids1.

menu_ids ::= [menu_ids1] \| [ ].		List of menu IDs.

menu_ids1 ::= menu_id \| menu_id,menu_ids1.

icon_ids ::= [icon_ids1] \| [ ].		List of icon IDs.

icon_ids1 ::= icon_id \| icon_id,icon_ids1.

node_id ::= string.		Unique node ID. Details.

edge_id ::= string.		Unique edge ID. Details.

menu_id ::= string.		Unique menu ID. Details.

menu_label ::= lang_string.		Text of menu entry. Details.

menu_mne ::= lang_string.		Mnemonic character. Details.

menu_acc ::= lang_string.		Accelerator key. Details.

icon_id ::= string.		Unique icon ID. Details.

type ::= string.		Arbitrary type. Details.

filename ::= string.		A string containing a valid file name. Note:* Windows^® users please use "/" (slash) instead of "\" (backslash) as a directory separator.*

context_id ::= string.		Context ID. Details.

window_id ::= string.		Window ID. Details.

string ::= ...		Informally: A character sequence without newline, carriage return and double quotes, enclosed by double quotes ("). For example: "This is a string". Special characters can be written in C-notation, e.g. \n for newline or \" for a quote inside the string.

lang_string ::=		Informally: A string beginning with "#%". Details.
	"#%..."
\|	string.

Basic Types

integer ::= ...		Informally: A positive number without fraction.

boolean ::= true \| false.

orientation ::= top_down \| bottom_up \| left_right \| right_left.

direction ::= up \| down \| left \| right.

btypes ::= [btypes1].		Types for file browser. Details.

btypes1 ::= btype \| btype,btypes1.

btype ::=		Text, pattern and title text.
	bt(lang_string,string,lang_string).

measures ::=		Measure unit. Details.
	cm \| inch.

menu_mod ::=		Modifier key. Details.
	alt \| shift \| control \| meta \| none \| lookup string.

manual_constraints ::=		Layout constraints. Details.
	modify \| preserve \| fixed \| freehand.

spline_drawing ::=		Edge style. Details.
	off \| graph \| all.

Microsoft, Windows, Windows NT and ActiveX are trademarks or registered trademarks of Microsoft Corporation in the United Staates and/or other countries. All other trademarks mentioned herein are the property of their respective owners. Information on this page is subject to change without notice. Please send comments regarding this web site to uDrawGraph.at.informatik.uni-bremen.de (Please replace '.at.' by '@'.) .